SnowyGUI/fabric/build.gradle.kts

repositories {
    maven {
        url = uri("https://maven.terraformersmc.com/releases")
        content { includeGroup("com.terraformersmc") }
    }
}

object Groups {
    const val Fabric: String = "net.fabricmc"
    const val FabricApi: String = "$Fabric.fabric-api"
}

architectury { platformSetupLoomIde(); fabric() }

dependencies {
    modImplementation("${Groups.Fabric}:fabric-loader:${rootProject.property("fabric_loader_version")}")
    modApi("${Groups.FabricApi}:fabric-resource-loader-v0:${rootProject.property("fabric_resource_loader_version")}")
    include("${Groups.FabricApi}:fabric-resource-loader-v0:${rootProject.property("fabric_resource_loader_version")}") { isTransitive = false }
    modRuntime(modCompileOnly("com.terraformersmc:modmenu:${rootProject.property("modmenu_version")}") {
        exclude(group = Groups.FabricApi, module = "fabric-resource-loader-v0")
    })
    implementation(project(path = ":common")) { isTransitive = false }
    add("developmentFabric", project(path = ":common")) { isTransitive = false }
    shadowC(project(path = ":common", configuration = "transformProductionFabric")) { isTransitive = false }
}