Yerbacon/Jenkinsfile

String cmake_generator() { return fileExists('/usr/bin/ninja') ? 'Ninja' : 'Unix Makefiles' }

def buildTarget(String path, String cmake_toolchain = '', boolean should_package = true) {
    final String system_name = !path.contains('mingw') ? sh(returnStdout: true, script: 'uname -s').trim() : 'Windows'
    final String linker = "/usr/bin/${path}-ld"
    final String build_directory = "cmake-build-${path}"
    final boolean not_packer_compatible = path.contains('riscv') || (path.contains('aarch64') && path.contains('mingw'))
    final boolean use_toolchain = cmake_toolchain != ''
    catchError(buildResult: 'UNSTABLE', stageResult: 'FAILURE') {
        // Note: CMake 3.20 or higher is needed
        cmakeBuild buildDir: build_directory, buildType: 'release', cleanBuild: true, installation: 'Latest',
            cmakeArgs: "--no-warn-unused-cli ${use_toolchain ? "-DCMAKE_TOOLCHAIN_FILE=${cmake_toolchain}" : "-DCMAKE_SYSTEM_NAME=\"${system_name}\" -DCMAKE_SYSTEM_PROCESSOR=\"${path.substring(0, path.indexOf('-'))}\" -DCMAKE_C_COMPILER=/usr/bin/${path}-gcc -DCMAKE_CXX_COMPILER=/usr/bin/${path}-g++ -DCMAKE_LINKER=${fileExists("${linker}.gold") ? "${linker}.gold" : linker} -DCMAKE_AR=/usr/bin/${path}-ar -DCMAKE_RC_COMPILER=/usr/bin/${path}-windres -DCMAKE_EXE_LINKER_FLAGS=-static"} -DNO_SELF_PACKER=${!(not_packer_compatible || use_toolchain) ? "OFF" : "ON"} -DIGNORE_MINIMAL_COMPILER_VERSION=ON -DNO_CCACHE=ON -DCMAKE_DISABLE_PRECOMPILE_HEADERS=ON",
            generator: cmake_generator()
        cmake arguments: "--build ./$build_directory --target ybcon", installation: 'Latest'
        if (should_package) {
            cpack installation: 'Latest', workingDir: build_directory
        }
    }
}

def upload_archives() {
    archiveArtifacts artifacts: 'cmake-build-*/*.deb, cmake-build-*/*.rpm, cmake-build-*/*.tar.gz, cmake-build-*/*.sh, cmake-build-*/*.js, cmake-build-*/*Windows.*.exe, cmake-build-*/*.zip', fingerprint: false
}

/* Required Plugins:
    - CMake
    - Sidebar Link
    - Workspace Cleanup
   Required Compilers:
    - G++ cross-compiler for riscv64
    - Musl cross-compiling toolchains (archives ending in "-cross" from https://musl.cc/#binaries) for x86_64, i686, armel, armhf and aarch64, unzipped into /usr/, along with soft links from /usr/bin/ to the binaries
    - Emscripten Clang (https://github.com/emscripten-core/emsdk) in /usr/share/
    - MinGW32 G++/Clang (https://github.com/mstorsjo/llvm-mingw) for x86_64, i686, armhf and aarch64, (unzip the content of the folder in the tar.xz file) in /usr/, along with soft links from /usr/bin/ to the binaries
   Optional Tools:
    - Ninja
    - UPX (d61edc9 or higher)
*/

pipeline {
    agent any

    options {
        buildDiscarder(logRotator(numToKeepStr: '48', artifactNumToKeepStr: '96'))
        timeout(time: 25, unit: 'MINUTES')
        sidebarLinks([
            [displayName: 'Gitea Repository', iconFileName: '/userContent/Yerbacon.png', urlName: 'https://gits.username404.fr/Username404-59/Yerbacon/src/branch/' + env.BRANCH_NAME]
        ])
    }
    triggers {
        pollSCM('*/10 * * * *')
    }
    stages {
        stage('Build') {
            matrix {
                agent any
                axes {
                    axis {
                        name 'TARGET'
                        values(
                            'x86_64-linux-musl',
                            'i686-linux-musl',
                            'armel-linux-musleabi',
                            'armv7l-linux-musleabihf',
                            'aarch64-linux-musl',
                            'riscv64-linux-gnu',
                            'x86_64-w64-mingw32',
                            'i686-w64-mingw32',
                            'armv7-w64-mingw32',
                            'aarch64-w64-mingw32'
                        )
                    }
                }
                stages {
                    stage('Compile and package') {
                        steps {
                            buildTarget("${TARGET}")
                        }
                    }
                    stage('Deploy') {
                        steps {
                            echo 'Deploying....'
                            upload_archives()
                        }
                    }
                }
            }
        }
        stage('Build using Emscripten') {
            steps {
                buildTarget('emscripten', '/usr/share/emsdk/upstream/emscripten/cmake/Modules/Platform/Emscripten.cmake', false)
            }
        }
        stage('Deploy') {
            steps {
                echo 'Deploying....'
                upload_archives()
            }
        }
    }
    post {
        always {
            cleanWs(cleanWhenNotBuilt: false, deleteDirs: true, disableDeferredWipeout: false, notFailBuild: true, skipWhenFailed: false)
        }
    }
}