String cmake_generator() { return fileExists('/usr/bin/ninja') ? 'Ninja' : 'Unix Makefiles' }
String no_compilation_cache_flags() { return '-DNO_CCACHE=ON -DCMAKE_DISABLE_PRECOMPILE_HEADERS=ON' }

def buildTarget(String path) {
    final String system_name = !path.contains('mingw') ? sh(returnStdout: true, script: 'uname -s').trim() : 'Windows'
    final String linker = "/usr/bin/${path}-ld"
    final String build_directory = "cmake-build-${path}"
    final boolean is_riscv = path.contains('riscv')
    // Note: CMake 3.20 or higher is needed
    cmakeBuild buildDir: build_directory, buildType: 'release', cleanBuild: true, installation: 'Latest',
        cmakeArgs: "--no-warn-unused-cli -DCMAKE_SYSTEM_NAME=\"${system_name}\" -DCMAKE_SYSTEM_PROCESSOR=\"${path.substring(0, path.indexOf('-'))}\" -DCMAKE_C_COMPILER=/usr/bin/${path}-gcc -DCMAKE_CXX_COMPILER=/usr/bin/${path}-g++ -DCMAKE_LINKER=${fileExists("${linker}.gold") ? "${linker}.gold" : linker} -DCMAKE_AR=/usr/bin/${path}-ar -DCMAKE_RC_COMPILER=/usr/bin/${path}-windres -DCMAKE_EXE_LINKER_FLAGS=-static -DNO_SELF_PACKER=${!is_riscv ? "OFF" : "ON"} -DIGNORE_MINIMAL_COMPILER_VERSION=ON ${no_compilation_cache_flags()}",
        generator: cmake_generator()
    cmake arguments: "--build ./$build_directory --target ybcon", installation: 'Latest'
    cpack installation: 'Latest', workingDir: build_directory
}

/* Required Plugins:
    - CMake
    - Sidebar Link
    - Workspace Cleanup
   Required Compilers:
    - G++ cross-compiler for riscv64
    - Musl cross-compiling toolchains (archives ending in "-cross" from https://musl.cc/#binaries) for x86_64, i686, armel, armhf and aarch64, unzipped into /usr/, along with soft links from /usr/bin/ to the binaries
    - Emscripten Clang (https://github.com/emscripten-core/emsdk) in /usr/share/
    - MinGW32 G++/Clang (https://github.com/mstorsjo/llvm-mingw) for x86_64, i686, armhf and aarch64, (unzip the content of the folder in the tar.xz file) in /usr/, along with soft links from /usr/bin/ to the binaries
   Optional Tools:
    - Ninja
    - UPX (d61edc9 or higher)
*/

pipeline {
    agent any

    options {
        buildDiscarder(logRotator(numToKeepStr: '48', artifactNumToKeepStr: '96'))
        timeout(time: 25, unit: 'MINUTES')
        sidebarLinks([
            [displayName: 'Gitea Repository', iconFileName: '/userContent/Yerbacon.png', urlName: 'https://gits.username404.fr/Username404-59/Yerbacon/src/branch/' + env.BRANCH_NAME]
        ])
    }
    triggers {
        pollSCM('*/10 * * * *')
    }
    stages {
        stage('Build') {
            steps {
                echo "Building the ${env.BRANCH_NAME} branch.."
                buildTarget('x86_64-linux-musl')
                buildTarget('i686-linux-musl')
                catchError(buildResult: 'SUCCESS', stageResult: 'UNSTABLE') {
                    cmakeBuild buildDir: "cmake-build-release-emscripten", buildType: 'release', cleanBuild: true, installation: 'Latest',
                        cmakeArgs: "-DCMAKE_TOOLCHAIN_FILE=\"/usr/share/emsdk/upstream/emscripten/cmake/Modules/Platform/Emscripten.cmake\" ${no_compilation_cache_flags()} -DNO_SELF_PACKER=ON",
                        generator: cmake_generator()
                    cmake arguments: "--build ./cmake-build-release-emscripten", installation: 'Latest'
                }
            }
        }
        stage('Build for other architectures') {
            steps {
                catchError(buildResult: 'SUCCESS', stageResult: 'FAILURE') {
                    buildTarget('armel-linux-musleabi')
                    buildTarget('armv7l-linux-musleabihf')
                    buildTarget('aarch64-linux-musl')
                    buildTarget('riscv64-linux-gnu')
                }
            }
        }
        stage('Build for other platforms') {
            steps {
                catchError(buildResult: 'SUCCESS', stageResult: 'UNSTABLE') {
                    buildTarget('armv7-w64-mingw32')
                    buildTarget('aarch64-w64-mingw32')
                }
                catchError(buildResult: 'SUCCESS', stageResult: 'FAILURE') {
                    buildTarget('x86_64-w64-mingw32')
                    buildTarget('i686-w64-mingw32')
                }
            }
        }
        stage('Deploy') {
            steps {
                echo 'Deploying....'
                archiveArtifacts artifacts: 'cmake-build-*/*.deb, cmake-build-*/*.rpm, cmake-build-*/*.tar.gz, cmake-build-*/*.sh, cmake-build-release-emscripten/*.js', fingerprint: false
                catchError(buildResult: 'SUCCESS', stageResult: 'SUCCESS') {
                    archiveArtifacts artifacts: 'cmake-build-*/*Windows.*.exe, cmake-build-*/*.zip'
                }
            }
        }
    }
    post {
        always {
            cleanWs(cleanWhenNotBuilt: false, deleteDirs: true, disableDeferredWipeout: false, notFailBuild: true, skipWhenFailed: false)
        }
    }
}